AutoStore: AutoCapture Folder Browse


If you're looking for an AutoCapture script to browse folders, then this post is for you. It uses a String List field to provide the folder navigation, as there isn't a tree field available in AutoCapture.

To get started, prepare an AutoStore configuration using the AutoCapture and Send to Folder components. Open the AutoCapture component, and add a new Form. Then ...



  1. Add a new field. We'll use Folder for the field Name.
  2. Set the Type option to String list.
  3. Make the field Required.
  4. Enable the Run script on field change setting.
  5. Enable the Run on form load setting.
  6. Click the [...] button to open the script editor.

Now, onto the script. Here's the short-list of what it does:
  • In the script, define the starting folder.
  • Move into a folder by selecting the item.
  • With a folder selected, the list is refreshed with any of its subfolders.
  • Navigate Back, and the list is refreshed with those folders.
  • Stops Back navigation once arrived the start path.
  • The the list value is the complete folder path.

The following sample script in its entirety is suitable for copy-and-paste. It includes everything else needed, including all the event handlers and helper methods. So, you can replace everything in your script editor's template with the following.

AutoCapture_BrowseFolder.vbs
'--------------------------------------------------------------------------------
' CONSTANTS
'================================================================================

' Reference a UNC Path or local physical disk ...
Const INITIAL_PATH = "C:\Test\Vendors"

' The Form Field Names ...
Const F_LISTFOLDER = "Folder"


'--------------------------------------------------------------------------------
' EVENT HANDLERS
'================================================================================

Sub Form_OnLoad(Form)
    If FolderExists(INITIAL_PATH) Then
        Dim strLoadName, strLoadPath, strLoadLabel, strLoadValue
        strLoadName = GetFolderName(INITIAL_PATH)
        strLoadPath = INITIAL_PATH
        strLoadLabel = strLoadName
        strLoadValue = strLoadPath
        Form.Fields.Field(F_LISTFOLDER).AddListItem strLoadLabel, strLoadValue
        
        Dim strSubFolders, arrSubFolders, strFolder
        strSubFolders = GetSubFolderPath(strLoadPath)
        arrSubFolders = Split(strSubFolders, vbCrLf)
        For Each strFolder In arrSubFolders
            arrParts = Split(strFolder, "|")
            Dim strNextName, strNextPath, strNextLabel, strNextValue
            strNextName = CStr(arrParts(0))
            strNextPath = CStr(arrParts(1))
            strNextLabel = " > [" & strNextName & "]"
            strNextValue = strNextPath
            Form.Fields.Field(F_LISTFOLDER).AddListItem strNextLabel, strNextValue
        Next
    End If
End Sub 


Function Form_OnValidate(Form)
    
End Function


Sub Field_OnChange(Form, FieldName, FieldValue)
    If FieldName = F_LISTFOLDER Then
        
        Dim strPickPath, strPickName
        strPickPath = FieldValue
        strPickName = GetFolderName(strPickPath)
        
        Form.Fields.Field(F_LISTFOLDER).RemoveAll
        
        If Not strPickPath = INITIAL_PATH Then
            Dim strBackPath, strBackName, strBackLabel, strBackValue
            strBackPath = CStr(GetParentFolderPath(strPickPath))
            strBackName = CStr(GetFolderName(strBackPath))
            strBackLabel = "< Back to [" & strBackName & "]"
            strBackValue = strBackPath
            Form.Fields.Field(F_LISTFOLDER).AddListItem strBackLabel, strBackValue
        End If
        
        Dim strCurrLabel, strCurrValue
        strCurrLabel = strPickName
        strCurrValue = strPickPath
        Form.Fields.Field(F_LISTFOLDER).AddListItem strCurrLabel, strCurrValue
        
        Dim strSubFolders, arrSubFolders, strFolder
        strSubFolders = GetSubFolderPath(strPickPath)
        arrSubFolders = Split(strSubFolders, vbCrLf)
        For Each strFolder In arrSubFolders
            arrParts = Split(strFolder, "|")
            Dim strNextName, strNextPath, strNextLabel, strNextValue
            strNextName = CStr(arrParts(0))
            strNextPath = CStr(arrParts(1))
            strNextLabel = " > [" & strNextName & "]"
            strNextValue = strNextPath
            Form.Fields.Field(F_LISTFOLDER).AddListItem strNextLabel, strNextValue
        Next
        
    End If
End Sub


Function Field_OnValidate(FieldName, FieldValue)
    
End Function


Sub Button_OnClick(Form, ButtonName)
    
End Sub


'--------------------------------------------------------------------------------
' HELPER METHODS
'================================================================================

' Return True or False if the Folder Path exists
Function FolderExists(folderPath)
    Dim blnReturn : blnReturn = False
    Dim objFSO : Set objFSO = CreateObject("Scripting.FileSystemObject")
    If objFSO.FolderExists(folderPath) Then
        blnReturn = True
    End If
    FolderExists = blnReturn
End Function

' Return "Name|Path" pair as newline-delimited string
Function GetSubFolderPath(folderPath)
    Dim objFSO, objFolder, objFolderCollection, objSubFolder, strReturn
    Set objFSO = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFSO.GetFolder(folderPath)
    Set objFolderCollection = objFolder.SubFolders
    For Each objSubFolder In objFolderCollection
        ' Build "Name|Path" pair values ...
        Dim strFolderName, strFolderPath, strValuePairs, strFolderList
        strFolderName = objSubFolder.Name
        strFolderPath = objSubFolder.Path
        strValuePairs = strFolderName & "|" & strFolderPath
        ' Build newline-delimited collection string ...
        If Len(strFolderList) = 0 Then
            strFolderList = strValuePairs
        Else
            strFolderList = strFolderList & vbCrLf & strValuePairs
        End If
    Next
    strReturn = strFolderList
    GetSubFolderPath = strReturn
End Function

' Return the Folder Name
Function GetFolderName(folderPath)
    Dim objFSO, objFolder, strReturn
    Set objFSO = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFSO.GetFolder(folderPath)
    strReturn = objFolder.Name
    GetFolderName = strReturn
End Function

' Return the Parent Folder Path
Function GetParentFolderPath(folderPath)
    Dim objFSO, strReturn
    Set objFSO = CreateObject("Scripting.FileSystemObject")
    strReturn = objFSO.GetParentFolderName(folderPath)
    GetParentFolderPath = strReturn
End Function


Only one more thing to setup. In the Send to Folder component, add the Folder RRT to the Folder Path. The value of the Folder field is the entire path of the selected folder.



Save the configuration, and start the service. Check out the results...



In closing, the script's INITIAL_PATH constant would be defined with the starting folder path for users to browse from. Keep the relationship between the AutoCapture client and the folder destination in mind. Starting at C:\ is from the server's perspective, not the user's system.

Also, if the name Folder is too generic for one's taste, you can change it in the AutoCapture Form. but you'll also need to modify the F_LISTFIELD constant in the script to be the same. This reference is handy because a single change is reflected throughout the respective parts in the script.

Enjoy!

Comments

Post a Comment

Popular posts from this blog

VBScript: Ensure Backslash Folder Path

Image
To preface what could be regarded as a very small thing, I am reminded of a common turn of phrase concerning the amount of perspiration that should be afforded to the "stuff" belonging to a particular size-category, and pretty sure there was a book written about that topic. Not to come across as disagreeable, but rather to invite a little balance based on my own general observations over time, an increase in cost with things such as time, money, even relationships, can be avoided when the "small stuff" is given the regard that it deserves. One of these tiny details has to do with string variables that reference folder paths within a script. There are times when it is important that a defined directory for a particular folder should and must always end with a backslash. As an example: folderPath = "C:\Example"   Of course, it really is not very difficult to manually enter that backslash into the path. folderPath = "C:\Example\"
Read more

AutoStore: Create a Custom RRT

Image
Have you ever needed to dynamically create a custom RRT for an AutoStore process? In my previous post AutoCapture Default Date , I described my very first AutoStore script where the value of an  Invoice Date  field in an AutoCapture Vendor Invoices  form was assigned a default value of the day prior from the current date. This Invoice Date  needs to be part of the file name, however its format contains slash (/) characters that cannot be part of the file name. So, we'll use the AutoStore VB/JScript process component to create a new RRT that's more friendly. To do so, we'll look at how to do the following: Bring the existing Invoice Date  value into the script Reformat the Invoice Date  to a Windows-friendly file name Output the reformatted Invoice Date to a new custom RRT After adding the VB/JScript process component in between the capture component and the Send to Folder route component of the configuration file, we open the AutoCapture component to conf
Read more

AutoStore: Workflow Loop Example

Image
Regardless of the programming language, a looping-statement is a common declaration for iterating through collections of things, such as the items of an array, records selected from a database, elements within an XML file, or the files inside a directory. A recent AutoStore challenge was presented where a script was used to fetch data in a process that returned either one or many items. This was the easy part. However, each return record needed to be specific to an individual Route based on one of those items returned. Example Example1@email.com Example1/URL Example2@email.com Example2/URL Example3@email.com Example3/URL Although the captured document being processed would be common for all in the return, the recipient belonging to one of these unique records should not be aware of  nor  receive any of the information that would belong to a different recipient. Because an unknown number of return records would be expected, this presents a challenge due to the fa
Read more